**SAS-Syntax zur Datenaufbereitung, Bildung von Summenwerten und erste Analysen für die drei Versionen des BesT (Kinder, Jugendliche und Eltern) (vgl. Keller/Naumann/Fegert, in CAPMH, 2021)**

*Ferdinand Keller, Dezember 2021*

Im folgenden findet sich eine Anleitung zum Einlesen der BesT-Daten aus den Beispieldatei-Vorlagen sowie die Umkodierung und Weiterverarbeitung mit Summenwerten von Subskalen.

Dabei werden die Daten aus den jeweiligen Excel-files eingelesen und in SAS work files gespeichert (Beispiel: „bestk“ für die Kinderbögen). Das Einlesen kann selbstverständlich auch aus anderen Datenformaten erfolgen, ebenso kann die work file-Bezeichnung geändert werden, muss aber dann jeweils angepasst werden.

Wichtig ist das Umpolen der dafür vorgesehenen Items im Jugendlichen- und im Elternbogen. Die Auswahl der Items für die Bildung der Summenwerte für Gesamt- und Subskalen wird ebenfalls dargestellt. Beides kann natürlich auch mit anderen Statistikprogrammen erledigt werden, wenn ein anderes bevorzugt wird. Die vorliegende SAS-Syntax soll vor allem den Algorithmus darstellen und weitere Skripte sind geplant (z.B. in R).

Rückmeldungen sind willkommen, ebenso eventuelle Skripte für andere Statistikpakete! Ferdinand.keller@uniklinik-ulm.de

\*-- einlesen Best-X Daten;

**proc** **import** datafile="c:\sas\_mein\best-kj\BesT\_K\_Klinikname\_2021.xlsx" out=bestk

 dbms=xlsx replace; getnames=yes;

**proc** **import** datafile="c:\sas\_mein\best-kj\BesT\_J\_Klinikname\_2021.xlsx" out=bestj

 dbms=xlsx replace; getnames=yes;

**proc** **import** datafile="c:\sas\_mein\best-kj\BesT\_E\_Klinikname\_2021.xlsx" out=beste

 dbms=xlsx replace; getnames=yes;

**run**;

\*--- einige initiale Auswertungen und Checks (am Beispiel Kinderbogen);

**proc** **contents** data=bestk; \* zeige Variablen im file und Eigenschaften;

 **run**;

**proc** **freq** data=bestk;

 table geschlecht alter station; \* Häufigkeiten;

**run**;

**proc** **means** data=bestk;

 var best\_nK1 -- best\_nK25; \* N, Mittelwerte, SD, Min, Max;

**run**;

**proc** **freq** data=bestk; \* Häufigkeiten ausgewählter Variablen;

 table best\_nK1 best\_nK18 best\_nK25 best\_nK26a best\_nK26b ;

**run**;

\*----- Kinderbögen bearbeiten ---;

**data** ki; set bestk;

 if auffaellig\_nk = 'x' then delete; \* auffällige Bögen entfernen;

 if nummer ne ' '; \* filtert leere Datensätze weg;

 array bestk{\*} best\_nK1 -- best\_nK20;

 if best\_nK18 >= **0** then tagesklinik = **0**; \* was angekreuzt?;

 if best\_nK18 = **7** then do;

 tagesklinik = **1**; \* war in Tagesklinik;

 best\_nK18 = **0**; \* wird zu missing im nächsten DO-loop;

 end;

 K24\_keineZwangsmass = **.**;

 if best\_nK24 = **0** then K24\_keineZwangsmass = **1**; \* keine Zwangsmass. angekreuzt;

 K25\_keinAnfassen = **.**;

 if best\_nK25 = **0** then K25\_keinAnfassen = **1**; \* kein Anfassen angekreuzt;

 \* umpolen Kinderversion;

 do i=**1** to **20**;

 if bestk[i] = **0** then bestk[i] = **.**; \* nicht stattgefunden als missing;

 end;

 do i=**1** to **20**;

 bestk[i] = **6** - bestk[i]; \* umpolen alle Items;

 end;

 best\_nk19 = **6** - best\_nk19; \* wieder zurück-umpolen (Angstitem);

 \* umpolen der beiden Items 24 und 25;

 if best\_nk24 = **0** then best\_nk24 = **.**; \* nicht stattgefunden als missing;

 if best\_nk25 = **0** then best\_nk25 = **.**; \* nicht stattgefunden als missing;

 best\_nk24 = **6** - best\_nk24; \* umpolen;

 best\_nk25 = **6** - best\_nk25; \* umpolen;

 label

 best\_nk1 = "Zeit gefallen"

 best\_nk2 = "mit Aufenthalt zufrieden"

 best\_nk3 = "Problem jetzt weg"

 best\_nk4 = "Zimmer gefallen"

 best\_nk5 = "Station gefallen"

 best\_nk6 = "Essen geschmeckt"

 best\_nk7 = "bei Untersuchung wohl gefühlt"

 best\_nk8 = "Aufklärung Medikamente"

 best\_nk9 = "Therapeut verstanden"

 best\_nk10= "Therapeut alles erzählen"

 best\_nk11= "Therapeut Zeit gehabt"

 best\_nk12= "Betreuer Problem verstanden"

 best\_nk13= "Betreuer nett"

 best\_nk14= "Personal ansprechbar"

 best\_nk15= "angeklopft an Zimmer"

 best\_nk16= "mit anderen verstanden"

 best\_nk17= "mitentscheiden Behandlung"

 best\_nk18= "Ausgangsregelung"

 best\_nk19= "Angst, dass andere mitkriegen"

 best\_nk20= "wieder in unsere Klinik"

 best\_nk24= "Zwangsmassnahmen erklärt"

 best\_nk25= "zu nahe oder angefasst"

 ;

 \* Summenscores Kinder;

 md\_best\_kneu = nmiss(of best\_nk1 - best\_nk18 best\_nk20 best\_nk24); \* Anzahl missings;

 genfak\_K = mean( of best\_nk1 - best\_nk18 best\_nk20 best\_nk24);

 fak1\_K\_ThBez = mean(of best\_nk8, best\_nk9, best\_nk10, best\_nk11, best\_nk12,

 best\_nk13, best\_nk14, best\_nk15, best\_nk17, best\_nk18, best\_nk24);

 fak2\_K\_Umgeb = mean(of best\_nk1, best\_nk2, best\_nk4, best\_nk5, best\_nk6, best\_nk20);

 label

 genfak\_K = "Gesamtwert (Kinder)"

 fak1\_K\_ThBez = "Therapeutische Beziehung"

 fak2\_K\_Umgeb = "Umgebung"

 md\_best\_kneu = "Anzahl missings (Kinder)"

 ;

**run**;

\*--- check neue Variablen;

\* Häufigkeiten der Kinder mit x missings;

**proc** **freq** data=ki;

 table md\_best\_kneu;

**run**;

\* check deskriptive Maße und Minimum und Maximum;

**proc** **means** data=ki;

 var best\_nk1 - best\_nK25 genfak\_K fak1\_K\_ThBez fak2\_K\_Umgeb;

**run**;

\*----- Elternboegen bearbeiten ---;

**data** el; set bestk bestj beste; \* hole Elternboegen aus allen 3 Dateien;

 if auffaellig\_ne = 'x' then delete; \* auffaellige Bögen weg;

 if nummer ne ' '; \* filtert leere Datensätze;

 array beste{\*} best\_ne1 -- best\_ne23;

 \* umpolen Elternversion;

 do i=**1** to **23**;

 if beste[i] = **0** then beste[i] = **.**; \* nicht stattgefunden als missing;

 end;

 do i=**4** to **21**;

 beste[i] = **6** - beste[i]; \* umpolen Item 4 - 21;

 end;

 label

 best\_ne1 = "insgesamt zufrieden"

 best\_ne2 = "Aufenthalt Kind geholfen"

 best\_ne3 = "Aufenthalt uns geholfen"

 best\_ne4 = "Aufklärung Krankheit"

 best\_ne5 = "Aufklärung Medikamente"

 best\_ne6 = "ernst nehmen (Therapeut)"

 best\_ne7 = "Einzelgespräche wirksam"

 best\_ne8 = "Familiengespräche wirksam"

 best\_ne9 = "Aufenthalt bringt viel"

 best\_ne10= "Mitsprache bei Therapien"

 best\_ne11= "Schweigepflicht"

 best\_ne12= "Zwangsmassnahmen"

 best\_ne13= "Mitsprache Kind bei Zimmer"

 best\_ne14= "Wochenendbeurlaubung"

 best\_ne15= "sanitäre Anlagen"

 best\_ne16= "Station schön"

 best\_ne17= "Mitsprache Entlassung"

 best\_ne18= "mehr Einzelgespräche"

 best\_ne19= "Privatsphäre Kind"

 best\_ne20= "Kind zurückziehen auf Stat."

 best\_ne21= "Behandlungsziele absprechen"

 best\_ne22= "wieder hierher"

 best\_ne23= "Angst, dass andere erfahren"

 ;

 \* Summenscores Eltern;

 md\_best\_eneu = nmiss( of best\_ne1 - best\_ne22); \* Anzahl missings (ohne das Stigma-Item);

 genfak\_E = mean( of best\_ne1 - best\_ne22);

 fak1\_E\_ThBez = mean(of best\_ne4, best\_ne5, best\_ne6, best\_ne7, best\_ne8, best\_ne9,

 best\_ne10, best\_ne11, best\_ne17, best\_ne18, best\_ne21);

 fak2\_E\_Umgeb = mean(of best\_ne13, best\_ne14, best\_ne15, best\_ne16, best\_ne19, best\_ne20);

 fak3\_E\_AllgZuf = mean(of best\_ne1, best\_ne2, best\_ne3, best\_ne22);

 label

 genfak\_E = "Gesamtwert (Eltern)"

 fak1\_E\_ThBez = "Beziehung zu Therapeut\_in"

 fak2\_E\_Umgeb = "Umgebung"

 fak3\_E\_AllgZuf = "Allgemeine Zufriedenheit"

 md\_best\_kneu = "Anzahl missings (Eltern)"

 ;

**run**;

\*-- check neue Variablen;

\* Häufigkeiten der Elternbögen mit missings;

**proc** **freq** data=el;

 table md\_best\_eneu;

**run**;

\* deskriptive Maße und Min und Max;

**proc** **means** data=el;

 var best\_ne1 - best\_ne23 genfak\_E -- fak3\_E\_AllgZuf;

**run**;

\*----- Jugendlichenboegen ---;

**data** ju; set bestj;

 if auffaellig\_nj = 'x' then delete; \* auffällige Bögen weg;

 if nummer ne ' '; \* entfernt leere Datensätze;

 array bestj{\*} best\_nj1 -- best\_nj29;

 J10\_keineSchule = **.**;

 if best\_nj10 = **0** then J10\_keineSchule = **1**; \* kein Schulbesuch angekreuzt;

 \* umpolen Jugendlichenversion;

 do i=**1** to **29**;

 if bestj[i] = **0** then bestj[i] = **.**; \* nicht stattgefunden als missing;

 end;

 do i=**4** to **25**;

 bestj[i] = **6** - bestj[i]; \* umpolen Item 4 - 25;

 end;

 label

 best\_nj1 = "insgesamt zufrieden"

 best\_nj2 = "Aufenthalt geholfen"

 best\_nj3 = "motiviert, mitzuarbeiten"

 best\_nj4 = "Aufklärung Krankheit"

 best\_nj5 = "Aufklärung Medikamente"

 best\_nj6 = "ernst nehmen (Therapeut)"

 best\_nj7 = "Einzelgespräche wirksam"

 best\_nj8 = "Familiengespräche wirksam"

 best\_nj9 = "ernst nehmen (Betreuer)"

 best\_nj10= "ernst nehmen (Lehrer)"

 best\_nj11= "Schweigepflicht"

 best\_nj12= "Zwangsmassnahmen"

 best\_nj13= "Ausgangsregelung"

 best\_nj14= "Essen"

 best\_nj15= "sanitäre Anlagen"

 best\_nj16= "sich zurückziehen mit Eltern"

 best\_nj17= "Station schön"

 best\_nj18= "Schulangebot"

 best\_nj19= "Mitsprache Therapien"

 best\_nj20= "Mitsprache Zimmer"

 best\_nj21= "Aufklärung poststationär"

 best\_nj22= "Klima Jugendliche"

 best\_nj23= "Privatsphäre"

 best\_nj24= "allein sein können"

 best\_nj25= "Ziele absprechen"

 best\_nj26= "Erwartungen erfüllt"

 best\_nj27= "wieder hierher"

 best\_nj28= "Angst, dass andere erfahren"

 best\_nj29= "zu nahe oder angefasst"

 ;

 \* Summenscores Jugendliche;

 md\_best\_jneu = nmiss( of best\_nj1 - best\_nj27); \* missings (ohne Stigma und anfassen);

 genfak\_J = mean( of best\_nj1 - best\_nj27);

 fak1\_J\_ThBez = mean(of best\_nj4, best\_nj5, best\_nj6, best\_nj7, best\_nj8,

 best\_nj9, best\_nj10, best\_nj11, best\_nj21, best\_nj25);

 fak2\_J\_Umgeb = mean(of best\_nj13, best\_nj14, best\_nj15, best\_nj16, best\_nj17,

 best\_nj20, best\_nj22, best\_nj23, best\_nj24);

 fak3\_J\_AllgZuf = mean(of best\_nj1, best\_nj2, best\_nj3, best\_nj26, best\_nj27);

 label

 genfak\_J = "Gesamtwert (Jugendliche)"

 fak1\_J\_ThBez = "Therapeutische Beziehung"

 fak2\_J\_Umgeb = "Umgebung"

 fak3\_J\_AllgZuf = "Allgemeine Zufriedenheit"

 md\_best\_jneu = "Anzahl missings (Jugendliche)"

 ;

**run**;

\*--- check neue Variablen;

**proc** **freq** data=ju;

 \* table erhebungsjahr; \*best\_nj1 best\_nj5 best\_nj10 best\_nj25 best\_nj28

 J5\_keineMedi J10\_keineSchule station;

 table station J10\_keineSchule md\_best\_jneu;

**run**;

**proc** **means** data=ju;

 var best\_nj1 - best\_nj29 genfak\_J -- fak3\_J\_AllgZuf;

**run**;

\*----- Start automatischer Output mit ODS;

\* (geht natürlich auch ohne ODS, mit output auf Bildschirm);

ods rtf file='c:\sas\_mein\best-kj\Erg\_best-kijuel-Klinikname\_2021.rtf';

ods NOPTITLE;

\* Kinder;

**data** raus; set ki;

title 'Haeufigkeitsverteilung (nach vorhandenen Kinderbogen)';

**proc** **freq**;

 table geschlecht alter station verweil\_14 beschluss;

 where best\_nk1 > **0**; \* Filterkriterium: Item 1 beantwortet;

**run**;

title 'Gesamtauswertung Kinderbogen';

**proc** **means** fw=**4**;

 var best\_nk1 - best\_nk20 best\_nk24 best\_nk25

 genfak\_K fak1\_K\_ThBez fak2\_K\_Umgeb;

 **run**;

title 'Unterteilung nach Geschlecht (Kinder)';

**proc** **sort** data=raus; by geschlecht; **run**;

**proc** **means** fw=**4**;

 var best\_nk1 - best\_nk20 best\_nk24 best\_nk25

 genfak\_K fak1\_K\_ThBez fak2\_K\_Umgeb;

 by geschlecht;

 **run**;

\*-- usw., analog für Jugendliche und Elternbögen.....;

ods rtf close;